[转帖]建立或删除autorun.inf文件夹

批处理代码如下：

CODE:
@echo off
mode con cols=70 lines=18
title 建立或删除autorun.inf文件夹
color 4f
cls
echo.
echo 免疫autorun类病毒，建立或删除autorun.inf文件夹 for /XP
echo ---------------------------------------------------------------
echo.
echo 此批处理会在每个分区的目录下建立autorun.inf\cfan.文件夹，默
echo 认的情况下是删不掉的，但可以用这个批处理删掉。在XP下测试通过。
echo.
echo 6618 2007年3月26日
echo.
echo [Y] 按 Y 键建立autorun.inf文件夹免疫autorun类病毒
echo [U] 按 D 键删除硬盘所有分区下的autorun.inf文件夹
echo [Q] 按其他任意键退出
echo -----------------------------------------------------------------
echo.
SET Choice=
SET /P Choice= 请选择要进行的操作：
IF /I '%Choice:~0,1%'=='y' goto md
IF /I '%Choice:~0,1%'=='d' goto del
exit
:md
for %%a in (c d e f g h i j k l m n o p q r s t u v w x y z) do del /a /f /q %%a:\autorun.inf>nul 2>nul & md %%a:\autorun.inf >nul 2>nul & %%a: >nul 2>nul & cd %%a:\autorun.inf >nul 2>nul & md cfan..\ >nul 2>nul & attrib +s +h +r %%a:\autorun.inf >nul 2>nul
cls
mode con cols=70 lines=10
color 2f
echo.&echo.&echo.
echo 已经在各分区的根目录下建立autorun.inf\cfan.文件夹免疫autorun病毒。
echo.
echo 感谢使用，按任意键退出...
pause>nul
exit
:del
for %%a in (c d e f g h i j k l m n o p q r s t u v w x y z) do rd /s /q %%a:\autorun.inf\cfan..\ >nul 2>nul & rd /s /q %%a:\autorun.inf >nul 2>nul
cls
mode con cols=70 lines=10
color e5
echo.&echo.&echo.
echo 已经删除各分区的根目录下建立autorun.inf\cfan.文件夹。
echo.
echo 感谢使用，按任意键退出...
pause>nul
exit